EVALUATE
SELECTCOLUMNS(
	INFO.PARTITIONS(),
	"Nom", [Name],
	"Requête", [QueryDefinition],
	"Type", 
		SWITCH(
			TRUE(),
			[Type]= 1, "Requête M",
			[Type]= 2, "Expression DAX",
			"Autres"
		),
	"Mode", 
		SWITCH(
			TRUE(),
			[Mode] = 0, "Import",
			[Mode] = 1, "Direct",
			"Autres"
		),
	"Actualisé", [RefreshedTime]
)

======================================================

EVALUATE
SELECTCOLUMNS(
	INFO.VIEW.MEASURES(),
	"Table", [Table],
	"Nom", [Name],
	"Dax", [Expression]
)

======================================================

EVALUATE
SELECTCOLUMNS(
    FILTER(
        INFO.CALCDEPENDENCY(),
        [OBJECT_TYPE] = "measure"
    ),
    "Table", [TABLE],
    "Nom", [OBJECT],
    "Dax", [EXPRESSION],
    "Table référencée", [REFERENCED_TABLE],
    "Objet référencé et type", [REFERENCED_OBJECT] & " / " & [REFERENCED_OBJECT_TYPE],
    "Dax référencé", [REFERENCED_EXPRESSION]
)

======================================================

EVALUATE
SELECTCOLUMNS(
	INFO.STORAGETABLECOLUMNS(),
	"Table", [DIMENSION_NAME],
	"Colonne", [ATTRIBUTE_NAME],
	"Taille", [DICTIONARY_SIZE]/1024
)
ORDER BY [Taille] DESC

======================================================

Dictionnaire de données = 
VAR _colonnes =
SELECTCOLUMNS(
    FILTER(
        INFO.VIEW.COLUMNS(),
        [Table] <> "Data Dictionary" && NOT([IsHidden])
    ),
    "Type", "Colonne",
    "Nom", [Name],
    "Table", [Table],
    "Description", [Description],
    "Dax", [Expression]
)
VAR _mesures =
SELECTCOLUMNS(
    FILTER(
        INFO.VIEW.MEASURES(),
        [Table] <> "Data Dictionary" && NOT([IsHidden])
    ),
    "Type", "Mesure",
    "Nom", [Name],
    "Table", [Table],
    "Description", [Description],
    "Dax", [Expression]
   )
VAR _tables =
SELECTCOLUMNS(
    FILTER(
        INFO.VIEW.TABLES(),
        [Name] <> "Data Dictionary" && NOT([IsHidden]) && [Name] <> "Calculations"
    ),
    "Type", "Table",
    "Nom", [Name],
    "Table", "n/a",
    "Description", [Description],
    "Dax", [Expression]
   )
RETURN
UNION(_colonnes,_mesures,_tables)

======================================================
